我有一个现有的 Web API 2 服务，需要修改其中一个方法以将自定义对象作为另一个参数，目前该方法有一个参数，它是来自 URL 的简单字符串。添加自定义对象作为参数后，我现在在从 .NET Windows 应用程序调用服务时收到 415 不支持的媒体类型错误。有趣的是，我可以使用 javascript 和 jquery ajax 方法成功调用此方法。

Web API 2 服务方法如下所示:

<HttpPost>
<HttpGet>
<Route("{view}")>
Public Function GetResultsWithView(view As String, pPaging As Paging) As HttpResponseMessage
   Dim resp As New HttpResponseMessage
   Dim lstrFetchXml As String = String.Empty
   Dim lstrResults As String = String.Empty

   Try
      '... do some work here to generate xml string for the response
      '// write xml results to response
      resp.Content = New StringContent(lstrResults)
      resp.Content.Headers.ContentType.MediaType = "text/xml"
      resp.Headers.Add("Status-Message", "Query executed successfully")
      resp.StatusCode = HttpStatusCode.OK
   Catch ex As Exception
      resp.StatusCode = HttpStatusCode.InternalServerError
      resp.Headers.Add("Status-Message", String.Format("Error while retrieving results from view {0}: {1}", view, ex.Message))
   End Try
   Return resp
End Function

该方法允许 POST 和 GET 因为 Paging 对象是可选的。如果我使用 GET 请求调用此方法，它会起作用。

调用服务的简单 .NET 客户端代码如下所示:

Dim uri As String = BASE_URI + "fetch/someview"
Dim resp As HttpWebResponse
Dim sr As StreamReader
Dim lstrResponse As String
Dim reqStream As Stream
Dim bytData As Byte()
Dim req As HttpWebRequest = WebRequest.Create(uri)
Dim lstrPagingJSON As String
Dim lPaging As New Paging
Try
   lPaging.Page = 1
   lPaging.Count = 100
   lPaging.PagingCookie = ""
   req.Method = "POST"
   lstrPagingJSON = JsonSerializer(Of Paging)(lPaging)
   bytData = Encoding.UTF8.GetBytes(lstrPagingJSON)
   req.ContentLength = bytData.Length
   reqStream = req.GetRequestStream()
   reqStream.Write(bytData, 0, bytData.Length)
   reqStream.Close()
   req.ContentType = "application/json"

   resp = req.GetResponse()

   sr = New StreamReader(resp.GetResponseStream, Encoding.UTF8)
   lstrResponse = sr.ReadToEnd
   '// do something with the response here
Catch exweb As WebException
   txtOutput.AppendText("Error during request: " + exweb.Message)
Catch ex As Exception
   txtOutput.AppendText(String.Format("General error during request to {0}: {1}", uri, ex.Message))
End Try

.NET 客户端在 4.5 框架上运行，服务在 4.5.2 框架上。 resp = req.GetResponse() 行会引发错误。我已经尝试过的一些事情:

• 在客户端，将 req.Accept 值设置为“application/xml”或 “文本/xml”
• 在服务方法中，删除该行 `resp.Content.Headers.ContentType.MediaType = "text/xml"
• 用一些静态 JSON 替换 XML 响应内容，尝试排除在请求中发送 JSON 并在响应中返回 XML 的任何问题

到目前为止，无论我尝试什么，我都会收到相同的 415 错误响应。

我提到当从 javascript 调用时这有效，这是我的 ajax 调用有效:

$.ajax({
   headers: {},
   url: "api/fetch/someview",
   type: "POST",
   data: "{Count:100,Page:1,PagingCookie:\"\"}",
   contentType: "application/json; charset=utf-8",
   dataType: "xml",
   success: function (data) {
      alert("call succeeded");
   },
   failure: function (response) {
      alert("call failed");
   }
});

在服务方面，路由配置或其他任何东西都没有什么特别之处，它几乎都是开箱即用的 Web API 2。我知道路由正在工作，调用被正确路由到该方法，他们不会出乎意料地去其他地方，那么我在.NET客户端中缺少什么？非常感谢任何帮助!

--- 更新 ---
我尝试创建一个全新的 Web API 服务以排除现有服务可能存在的任何问题，我创建了一个 Controller ，它具有一个将自定义对象作为参数的单一方法。然后我尝试从 .NET 客户端调用它并得到同样的错误。我也尝试使用 WebClient 而不是 HttpWebRequest，但仍然得到相同的错误。这也是以前使用 Web API(在 Web API 2 之前)对我有用的东西。

--- 更新 ---
我还尝试使用 Web API 1 创建一个新的 Web 应用程序，当我使用 POST 调用它时，我的复杂对象参数现在为空。我有另一个运行 Web API 1 的 Web 服务，并验证我仍然可以使用复杂的对象成功调用它。无论我的问题是什么，它似乎与客户端和服务器之间传递的 JSON 有关。我检查了我发送的 JSON 及其有效性，对象定义也是客户端和服务器之间的完全匹配，因此 JSON 应该能够被服务器解析。

最佳答案

已解决
在用这个问题把我的头撞到墙上几天之后，看起来这个问题与客户端和服务器之间的内容类型协商有关。我使用 Fiddler 更深入地研究了来自客户端应用程序的请求详细信息，这是 fiddler 捕获的原始请求的屏幕截图:

显然缺少的是 Content-Type header ，尽管我在原始帖子中的代码示例中设置了它。我觉得奇怪的是，即使我正在设置 Content-Type 也从未通过它，所以我再次查看了调用不同 Web API 服务的其他(工作)代码，唯一的区别是在这种情况下，我碰巧在写入请求正文之前设置了 req.ContentType 属性。我对这个新代码进行了更改，并且做到了，Content-Type 现在出现了，我从 Web 服务获得了预期的成功响应。我的 .NET 客户端的新代码现在如下所示:

req.Method = "POST"
req.ContentType = "application/json"
lstrPagingJSON = JsonSerializer(Of Paging)(lPaging)
bytData = Encoding.UTF8.GetBytes(lstrPagingJSON)
req.ContentLength = bytData.Length
reqStream = req.GetRequestStream()
reqStream.Write(bytData, 0, bytData.Length)
reqStream.Close()
'// Content-Type was being set here, causing the problem
'req.ContentType = "application/json"

就是这样，只需要在写入请求正文之前设置 ContentType 属性

我相信这种行为是因为一旦将内容写入主体，它就会流式传输到被调用的服务端点，与请求相关的任何其他属性都需要在此之前设置。如果我错了或者需要更多详细信息，请纠正我。

关于json - 调用 Web API 2 端点时出现 HTTP 415 不支持的媒体类型错误，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/34660641/