我目前正在为我的 Android 手机使用一些 TImage 控件并控制它们的位置和角度在 Firemonkey 中制作 2D 游戏。就那么简单。我尝试使用我正常的循环方式，它在 Windows 中运行良好/完美，但在 Android 上失败。

方法 #1:“无限”循环(坏)

我的主要问题是我想通过使用像这样的“无限循环”来避免不需要的/意外的行为，我必须调用 Application.ProcessMessages():

while (Game.IsRunning()) do
begin
  { Update game objects and stuff }
  World.Update();


  { Process window messages, or the window will not respond anymore obviously }
  Application.ProcessMessages(); { And thats what i want to avoid }
end;

问题是，当我陷入循环并调用过程来处理消息时，我会遇到很多问题，而且我认为这不是一个好方法。

方法 #2:TTimer(想都别想 ;-))

由于 TTimer 在很多方面都很糟糕并且不适合用于此类事情，所以我只放置一个具有最小间隔的 TTimer 的方法就失效了。此外，我从未尝试过其他计时器，但如果有真正用于游戏的计时器，我当然会尝试 :)

方法 #3:OnIdle - 我通常如何在 Windows 上执行此操作

在 Windows 上，我可以使用 Application.OnIdle-Event。

procedure GameLoop(Sender: TObject; var Done: Boolean);
begin
  { Update game objects and stuff }
  World.Update();

  { Set done to false }
  Done := False;
end;

...

Application.OnIdle := GameLoop;

每次应用程序在 windows 消息上空闲时都会调用它。与#1 相比，性能似乎相同或差一点，并且整体架构更加可靠，这就是我通常使用这种方法的原因。然而，在 Android 上，当与 TForm.MouseMove 结合使用时，它的调用方式似乎有所不同。在 Windows 上 OnIdle 保持完美运行的地方，在 Android 上它会在从触摸输入调用 TForm.MouseMove 时滞后/停止(RAD Studio 自动将其编译为触摸事件)

不过，我可以通过调用 Application.DoIdle 在 MouseMove 事件中自己触发 OnIdle 并“协助”“循环”，我认为它错过了 beimg 调用但是这也非常糟糕，并且在使用触摸输入时再次带来不需要的行为和更差的性能。

这让我回到了方法#1，它目前似乎在 Android 上效果最好。是否有任何其他方法可以创建一个可靠的方法(一个持续快速调用的事件，如 OnIdle 等)来创建这样一个循环或任何方法来避免我在方法 #3 中与 MouseMove-Events 结合时面临的问题？似乎 Android 手机不够强大，无法在表单事件和世界更新旁边有足够的“空闲时间”

此外，我是否可以考虑为世界逻辑使用线程，并在其旁边使用主窗体/线程上的方法 #1 来更新渲染？通过无限循环(使用 Application.ProcessMessages())更新表单控件并从处理世界、对象等的另一个线程获取显示的数据是否安全？

最佳答案

我认为一个有效的选择是实现 TAnimation 并覆盖 ProcessAnimation。通过 TAnimator 运行时会自动安排 TAnimation。

  TGameLoop = class(TAnimation)
  protected
    procedure ProcessAnimation; override;
  end;
  [...]
  procedure TGameLoop.ProcessAnimation;
  begin
    //call updates
  end;

然后像这样开始:

procedure TForm1.FormCreate(Sender: TObject);
begin
  FLoop := TGameLoop.Create(Self);
  FLoop.Loop := True;
  FLoop.Name := 'GameLoop';
  FLoop.Parent := Self;
  TAnimator.StartAnimation(Self, 'GameLoop');
end;

默认情况下，动画的 FPS 设置为 60。我现在无法弄清楚的一件事是如何仅使用 TAnimation 的属性来计算自上次调用以来的 Deltatime。这对于处理可变帧时间至关重要。但是您可以使用 System.Diagnostics.TStopwatch 自己做这件事。在 ProcessAnimation 开始时停止 watch 并获取 Ticks，在完成 ProcessAnimation 后开始一个新的。

编辑: Deltatime 的基本示例(自上次调用以来耗时，以秒为单位)。假定您在 Form1 上放置了一个 ViewPort3D，添加了名为 Cube1 的 TCube，在与 Form1 相同的单元中声明了 TGameLoop(我知道，丑陋，但 Demopurpose)和 TGameLoop 具有类型为 TStopWatch 的 Field FWatch。

procedure TGameLoop.ProcessAnimation;
var
  LDelta: Single;
begin
  FWatch.Stop;
  LDelta := FWatch.ElapsedTicks / FWatch.Frequency;
  Form1.Cube1.RotationAngle.Y := Form1.Cube1.RotationAngle.Y + 50*LDelta;
  FWatch := TStopwatch.StartNew();
end;

EDIT2:一个更好的例子，它在整个游戏生命周期内更好地分布舍入/测量误差。我们不是只在调用之间进行测量，而是从第一帧开始进行测量。 TGameLoop 有一个新字段 FLastElapsedTicks(Double)

procedure TGameLoop.FirstFrame;
begin
  FWatch := TStopWatch.StartNew();
end;

procedure TGameLoop.ProcessAnimation;
var
  LDelta: Single;
  LTickDelta, LElapsed: Double;
begin
  LElapsed := FWatch.ElapsedTicks;
  LTickDelta := LElapsed - FLastElapsedTicks;
  FLastElapsedTicks := LElapsed;
  LDelta := LTickDelta / FWatch.Frequency;
  Form1.Cube1.RotationAngle.Y := Form1.Cube1.RotationAngle.Y + 50*LDelta;
end;

关于android - Android 版 Firemonkey 中的游戏循环，我们在Stack Overflow上找到一个类似的问题： https://stackoverflow.com/questions/40082484/